eksperyment.doc

<item itemA>

/ 1 = "A01.jpg"

/ 2 = "A02.jpg"

/ 3 = "A03.jpg"

/ 4 = "A04.jpg"

</item>

<item itemB>

/ 1 = "B01.jpg"

/ 2 = "B02.jpg"

/ 3 = "B03.jpg"

/ 4 = "B04.jpg"

/ 5 = "B05.jpg"

/ 6 = "B06.jpg"

/ 7 = "B07.jpg"

/ 8 = "B08.jpg"

/ 9 = "B09.jpg"

/ 10 = "B10.jpg"

/ 11 = "B11.jpg"

/ 12 = "B12.jpg"

</item>

<picture picA>

/ items = itemA

</picture>

<picture picB>

/ items = itemB

</picture>

*******************************

Ekrany

*******************************

<trial picA>

/ stimulusframes = [1=picA]

/ pretrialpause = 250

/ trialduration = 1000

/ validresponse = (" ", noresponse)

/ correctresponse = (" ")

/ errormessage = (badA, 750)

</trial>

<trial picB>

/ stimulusframes = [1=picB]

/ pretrialpause = 250

/ trialduration = 1000

/ validresponse = (" ", noresponse)

/ correctresponse = (noresponse)

/ errormessage = (badB, 750)

</trial>

<block picMix>

/ trials = [1-24 = noreplacenorepeat (picA, picB,picB,picB) ]

</block>

*******************************

Sygnalizacja błędów

*******************************

<text badA>

/ items = ("była~n piłka!")

/ fontstyle = ("", 10%, true)

/ vjustify = center

/ size = (30%, 50%)

/ txcolor = (255,255,255)

/ txbgcolor = (0,0,0)

</text>

<text badB>

/ items = ("to nie~n piłka!")

/ fontstyle = ("", 10%, true)

/ vjustify = center

/ size = (30%, 50%)

/ txcolor = (255,255,255)

/ txbgcolor = (255,0,0)

</text>

*******************************

Instrukcja

*******************************

<defaults>

/ fontstyle = ("", 4%)

</defaults>

<text introGora>

/ items = ("Witamy w teście koncentracji uwagi!~n

Na ekranie ukaże się ciąg obrazków.

Twoim zadaniem jest naciskanie spacji WYŁĄCZNIE wtedy,

gdy na ekranie widać jedną z piłek:")

/ size = (90%, 20%)

/ vposition = 20%

/ hjustify = left

</text>

<text introDol>

/ items = ("Obrazki ukazują się tylko na 1 sekundę.

Ułóż palce na klawiszu spacji i naciśnij, aby rozpocząć.")

/ size = (90%, 20%)

/ vposition = 80%

/ hjustify = left

</text>

<picture picA1>

/ items = itemA

/ select = 1

/ hposition = 20%

</picture>

<picture picA2>

/ items = itemA

/ select = 2

/ hposition = 30%

</picture>

<picture picA3>

/ items = itemA

/ select = 3

/ hposition = 40%

</picture>

<picture picA4>

/ items = itemA

/ select = 4

/ hposition = 50%

</picture>

<trial intro>

/ stimulusframes = [1= picA1,picA2,picA3,picA4, introGora, introDol]

/ recorddata = false

/ correctresponse = (" ")

</trial>

<block intro>

/ trials = [1=intro]

</block>

*******************************

Podsumowanie

*******************************

<instruct >

/ nextkey = (" ")

/ finishlabel = "spacja -> dalej"

</instruct>

<page summary>

Popełnione błędy: ^^

spacja, gdy nie było piłki: <% trial.picB.errorcount %>^

brak spacji, gdy była piłka: <% trial.picA.errorcount %>

</page>

*******************************

Eksperyment

*******************************

<expt>

/ blocks = [1=intro; 2=picMix]

/ postinstructions = (summary)

</expt>